Компонент slider в FlashDevelop AS3.0 проекте.

Хоть и юзать будем програмулю FlashDevelop, однако slider затащен будет из Flash CS3, чего-то не очень нравятся флексовые компоненты, они тяжелые, те. swf файл получается более 100 килобайт. Я же в Flash CS3 перетягиваю компонент из панельки компонентов, это будет slider (ctrl+F7) в библиотеку (ctrl+L). Все... Работка в Flash CS3 закончена, почти. Надо нажать на publish settings (ctrl+shift+F12) там есть вкладка Flash, на ней надо поставить галочку
[v] Export swc. Компилим ctrl+Enter.
Полученную swc копируем в AS3.0 проект FlashDevelop, кликаем на ней правой кнопочкой мыши, ставим галочку напротив
[v] Add to library.
Пишем такой документ класс
package  
{//SliderDemo
	import fl.events.*;
	import fl.controls.*;
	import flash.display.*;
	import flash.text.*;
	
	/**
	 * ...
	 * @author http://www.murmadillo.tut.su/
	 */
	public class SliderDemo extends Sprite
	{
		public var slider:Slider,
		sliderLabel:TextField,
		myLabel:TextField,
		positionTxt:TextField;

		public function SliderDemo() 
		{
			addChild(slider = new Slider);
			slider.x=slider.y=100;
			slider.liveDragging = true;
			slider.setSize(200,10);
			slider.rotation = 90;
			slider.maximum = 100;
			slider.minimum = 0;
			slider.tickInterval = 5;

			addChild(sliderLabel = new TextField);
			sliderLabel.x=100;
			sliderLabel.y = 110;
			
			addChild(myLabel = new TextField);
			myLabel.x=100;
			myLabel.y=130;

			addChild(positionTxt = new TextField);
			positionTxt.autoSize = TextFieldAutoSize.LEFT;
			positionTxt.x=100;
			positionTxt.y=150;
			
			slider.addEventListener(SliderEvent.CHANGE, analyzeSliderInput);
			slider.addEventListener(SliderEvent.THUMB_DRAG, analyzeSliderInput);

			slider.addEventListener(SliderEvent.CHANGE, announceChange);

			sliderLabel.autoSize = TextFieldAutoSize.LEFT;
			sliderLabel.text = "Select and move slider with keyboard or mouse";
			myLabel.autoSize = TextFieldAutoSize.LEFT;
			myLabel.text = "Lorem ipsum lorem ipsum lorem ipsum.";
		}

		private function analyzeSliderInput(e:SliderEvent):void {
			switch (e.triggerEvent) {
				case InteractionInputType.MOUSE :
					sliderLabel.text = "Slider has been moved with mouse";
					break;
				case InteractionInputType.KEYBOARD :
					sliderLabel.text = "Slider has been moved with keyboard";
					break;
				default :
					break;
			}
		}

		function announceChange(e:SliderEvent):void {
			//trace("Slider value is now: " + e.target.value);
			positionTxt.text = "Slider value is now: " + e.target.value;
		}
		
	}
	
}
Пробуем компилить
выдает ошибку
D:\FLEX\Slider\SliderDemo.as(54): col: 41 Error: Тип не найден или не является константой времени компиляции: SliderEvent.
Хм... Фигово... Опять идем в CS3 делаем там New Symdol - MovieClip - class [UseSliderEvent], создаем в той же директории файл UseSliderEvent.as пишем там такой код
//UseSliderEvent
package
{
import fl.events.*;
import flash.display.*;
	public class UseSliderEvent extends Sprite
	{
		
		public function UseSliderEvent() 
		{
			new SliderEvent('',0,'','');
		}
		
	}
	
}
Зачем нужен этот класс??? Ну как-же он юзает нужный нам SliderEvent, который вкомилится в проект и будет доступен через библиотеку во FlashDevelop проекте, опять пробуем компилить и теперь все работает.

Архив, содержащий проект с компонентом Slider, который находится в swc библиотеке.